• Là où POSIX utilise le slash / comme séparateur pour les chemins de fichier, AppleScript utilise le symbole deux points :.
• Vous pouvez utiliser les deux points : dans un nom de fichier POSIX, et vous pouvez utiliser le slash / dans un nom de fichier AppleScript : ils sont traduits l'un par l'autre.
• Pour traduire un chemin UNIX (d'un fichier, ou d'un dossier, valide ou non) en une référence AppleScript à un fichier (file reference), utilisez la commande POSIX file. POSIX file renvoie une file reference que votre script pourra utiliser directement pour créer ou manipuler un fichier.

  set p to "/usr/local/bin/"
  set a to POSIX file p
     -- file "Macintosh HD:usr:local:bin:"

• Pour traduire un chemin AppleScript (d'un fichier ou d'un dossier, valide ou non) en un chemin POSIX, utilisez POSIX path of.

  set a to "Macintosh HD:usr:local:bin:"
  set p to POSIX path of a
     -- "/usr/local/bin/"

  POSIX path comprend les file references AppleScript.

  set a to alias "Macintosh HD:usr:local:bin:"
  set p to POSIX path of a
     -- "/usr/local/bin/"
  set a to file "Macintosh HD:usr:local:bin:"
  set p to POSIX path of a
     -- "/usr/local/bin/"

• Un nom de fichier peut inclure des caractères qui nécessitent de rajouter des caractères pour pouvoir les passer à une commande shell. Utilisez quoted form pour obtenir une forme adaptée aux commandes shell (avec des guillemets simples).

  set a to path to application support
  set p to POSIX path of a
    --  "/Library/Application Support/" -- contient un espace
  do shell script "ls " & p -- ne marche pas
    --  ""
  
  do shell script "ls " & quoted form of p -- marche correctement
    --  Result:
  Adobe
  Lexmark Z53 Files
  etc.

• Les dossiers réservés peuvent avoir des noms divers, par exemples traduits selon la langue du système. Au lieu d'accéder à ces dossiers par leur nom, utilisez plutôt la commande path to et les mots-clés correspondant. La plupart des mots-clés sont donnés dans le dictionnaire de StandardAdditions.osax (sélectionnez path to, et appuyez sur ⌘⇧F).
  path to accepte un paramètre from pour spécifier user domain, local domain ou system domain.

  set a to path to application support from user domain
  set p to POSIX path of a
    --  "/Users/<login>/Library/Application Support/"

  Pour une liste exhaustive des mots-clés reconnus par path to, utilisez l'outil suivant : menu User Scripts > More Smile commands > Scripting > Path to.